# 使用须知：
# 点击主窗口的Control菜单下的New praat script按钮，以建立一个新的脚本语言编辑窗口，然后将脚本语言拷贝到脚本语言编辑窗口中；
# 打开一个声音，并按对象列表右侧的Edit按钮来编辑这个声音，选定Sound对象编辑器中Spectrum菜单下的Show Spectrogram按钮，以及Formant菜单下的Show Formant按钮，以保证在Sound编辑器中能够看见声音的宽带语图（表现为灰度图）和共振峰（表现为红色的点）；
# 将游标定位到需要测量共振峰的时间位置上（一般定位在共振峰数据比较稳定的地方或发生变化的地方，而不能放在那些红点散乱的位置）；
# 然后按脚本编辑器的菜单"Run"下的"Run"按钮即可执行；
# 这个程序将提取出游标位置的前三个共振峰频率数据和带宽数据，并把它写到一个新建立的TextGrid文件之中，在TextGrid对象中它们之间用"-"分开，"-"之前表示共振峰的中心频率值，"-"之后表示共振峰的带宽；如果所提取出来的数据不够准确，请在TextGrid对象中进行修改，最后请记住保存TextGrid对象中的数据。
# 作者：笨笨熊


nameofSound$=selected$("Sound")
nameofTextGrid$=nameofSound$+"Formant"

select all
numofTextGrid=numberOfSelected("TextGrid")

find=0
if numofTextGrid>0
     toEof=0
     i=0
     while find=0 and toEof=0
            i=i+1
            if  selected$("TextGrid",i)=nameofTextGrid$
                     find=1
            endif
            if i=numofTextGrid
                   toEof=1
            endif
     endwhile
endif

if find=0
        select Sound 'nameofSound$'
        To TextGrid... "F3 F2 F1" F3 F2 F1
        Rename... 'nameofTextGrid$'
endif


editor Sound 'nameofSound$'
        curTime=Get cursor
        for i from 1 to 3
                f=Get formant... 'i'
                b=Get bandwidth... 'i'
                tt'i'$=fixed$(f,0)+"-"+fixed$(b,0)
        endfor
endeditor

select TextGrid 'nameofTextGrid$'
for i from 1 to 3
        k=4-i
        t$=tt'i'$
        Insert point... 'k' 'curTime' 't$'
endfor

select Sound 'nameofSound$'